|| A class.
{define-class public Person

  || A private field
  field private _age:int = 0

  || Get someone's age.
  {getter public {age}:int
    {return self._age}
  }

  || Set someone's age.
  {setter public {age years:int}
    {if years < 0 then
        {error "Age in years must be >= 0."}
    }
    set self._age = years
  }
}

|| Create an object of type Person
{let child:Person = {Person}}

|| Use the "age" getter
{value child.age}

|| Use the "age" setter
{set child.age = 7}
       

|| Define the superclass Person
{define-class public Person

  || A private field
  field private _age:int = 0

  || Get a Person's age.
  {getter public {age}:int
    {return self._age}
  }

  || Set a Person's age.
  {setter public {age years:int}
    {if years < 0 then
        {error "Age in years must be >= 0."}
    }
    set self._age = years
  }
}
|| Define a subclass, Child
{define-class public Child {inherits Person}
  field public-get private-set age-in-months:int = 0

  || Require a Child to be under 21,
  || by overriding the inherited age setter
  {setter public {age years:int}
    {if years >= 21 then
        {error "Age in years must be < 21."}
     else
        || invoke parent class setter
        set super.age = years
        || use private setter from this class
        set self.age-in-months = years * 12
    }
  }
}

{let child:Child = {Child}}

|| Use setter from Child class; also try setting age to 22!
{set child.age = 3}

|| Use getter from Person class to
How many years old is your child? ... {value child.age}

|| Uses public getter from Child class
How many months old is your child? ... {value child.age-in-months}