{let buffer:TextFlowBox =
    {TextFlowBox width=5in, border-width=1pt,
        border-color="black", margin=2pt
    }
}
{VBox
    buffer,
    {CommandButton
        label="Select a URL to Read",
        {on Action do
            {buffer.clear} 
            let file-url:#Url = {choose-location 
                                    default-location = {url "http://www.curl.com"},
                                    title = "Demonstrate HTTP monitoring",
                                    label = "Read from www.curl.com"
                                }
            {if-non-null file-url then
                let myinput:#TextInputStream
                {try
                    set myinput={read-open file-url}
                 catch err:IOException do
                    {buffer.add {text A problem occurred while opening the file:
                                    {value err.message}
                                }
                    }
                }
                {if-non-null myinput then
                    {try
                        {until myinput.end-of-stream? do
                            {buffer.add {myinput.read-line}}}

                     catch err:IOException do
                        {error
                            "A problem occurred while reading the file: "
                            & err.message
                        }
                     finally
                        {myinput.close}
                    }
                }
            }
        }
    }
}