cell-prototype

Table に追加される要素をパッケージ化します。

...: cell-prototype に対する引数には、1 つの Graphic、あるいは Graphic に強制変換できるもの (これは、実際に Table に追加される要素に変換される) が含まれなくてはなりません。追加引数は、次のケースのいずれかに当てはまる、name=value の形式のキーワード引数でなくてはなりません。

name が row または column の場合、value は行または列の番号を指定する整数 (最初の行または列として 0 で始まる) でなくてはなりません。この種類のキーワード引数は、この row-prototype に含まれるオブジェクトが Table に追加される前に、Table の挿入カーソルを指定の行または列位置に移動します。これらのキーワードはどのように組み合わせても有効です。両方を省略することも、1 つのみを使用することも、両方を使用することも可能です。
name が colspan または rowspan の場合、value は、このセルが広がる列または行の番号を指定する整数でなくてはなりません。これらのキーワード引数のいずれかが存在しない場合、単一の列または行に収まる要素に相当する、1 のスパン値が使用されます。
その他の name は、この row-prototype に相当する、TableCell オブジェクトに設定されるオプションの名前として処理されます。

戻り値

セルを説明する TableContentPrototype です。

例

cell-prototype を使用して要素を追加し、それから次に示されるように color オプションを指定することにより、カラフルな乗数テーブルを生成することができます。

例

{value
    let t:Table = {Table halign="right"}
    let size:int = 10
    {for i:int = 1 to size do
        {for j:int = 1 to size do
            let prod:int = i * j
            {t.add
                {cell-prototype row = i - 1, column = j - 1,
                      color = {if prod mod 2 == 0
                               then "green"
                               else "red"},
                      prod}}}}
    t}

colspan および rowspan キーワード引数の操作、ならびに既存 Table 要素の上にオブジェクトを追加した場合の影響は、次の例で説明されています。この例は、乗数テーブルの上に、様々な水平および垂直スパンを持つ Rule を格納します。Rule は、テキストよりも遥かに伸長性が高いので、自動的に伸長し、割り当てられた Table の領域を埋めます。

例

{value
    let t:Table = {Table halign="right"}
    let size:int = 10
    {for i:int = 1 to size do
        {for j:int = 1 to size do
            let prod:int = i * j
            {t.add
                {cell-prototype row = i - 1, column = j - 1,
                      color = {if prod mod 2 == 0
                               then "green"
                               else "red"},
                      i * j}}}}
    {t.add {cell-prototype row=1, column=2, colspan=2, rowspan=2,
                 {Rule color="orange"}}}
    {t.add {cell-prototype row=2, column=6, rowspan=3,
                 {Rule color="blue"}}}
    {t.add {cell-prototype row=4, column=3, colspan=3,
                 {Rule color="brown"}}}
    {t.add {cell-prototype row=6, column=4, colspan=4, rowspan=3,
                 {Rule color="pink"}}}
    t}