{define-proc package {make-table
                         cell-border-style:BorderStyle,
                         cell-border-color:FillPattern =
                             FillPattern.blue,
                         cell-border-spec:#BorderSpec = null
                     }
    {return
        {Table
            columns = 3,
            width = 7cm,
            height = 3cm,
            background = FillPattern.silver,                
            border-width = 1pt,
            border-color = FillPattern.black,
            cell-border-style = cell-border-style,
            cell-border-color = cell-border-color,
            cell-border-width = 2pt,
            cell-margin = 5pt,                
            cell-border-spec = cell-border-spec,
            "Apple", "Banana", "Grapes",
            "Papaya", "Strawberry", "Guava"
        }
    }
}

{spaced-hbox
    margin = 2pt,
    || Note that this Table is setting the left and right cell 
    || border width to 0pt. Since top and bottom cell border width
    || are not specified in the BorderSpec they will be equal to 
    || the value of the cell-border-width option on the Table. 
    {make-table
        BorderStyle.flat,
        cell-border-spec = 
            {BorderSpec
                left-border-width = 0pt,
                right-border-width = 0pt
            }
    },
    || Note that this Table is setting the left and right cell 
    || margin to 0pt. Since top and bottom cell margin are not 
    || specified in the BorderSpec they will be equal to the 
    || value of the cell margin option on the Table. 
    {make-table 
        BorderStyle.flat,
        cell-border-spec =
            {BorderSpec
                left-margin = 0pt,
                right-margin = 0pt
            }                
    }
}

{value
    let size:int = 10
    let t:Table = {Table halign="right"}
    {for i:int = 1 to size do
        {for j:int = 1 to size do
            {t.add
                row = i - 1,
                column = j - 1,
                i * j
            }
        }
    }
    t
}

{value
    let size:int = 10
    let t:Table = {Table columns=size, halign="right"}
    {for i:int = 1 to size do
        {for j:int = 1 to size do
            {t.add i * j}
        }
    }
    t
}

{value
    let size:int = 10
    let t:Table = {Table halign="right", valign="origin"}
    {t.add
        {row-prototype
            {text N},
            {text N{superscript 2}},
            {text N{superscript 3}},
            {text N{superscript 4}}
        }
    }
    {for i:int = 1 to size do
        {t.add
            {row-prototype
                i,
                i * i,
                i * i * i,
                i * i * i * i
            }
        }
    }
    t
}

{value
    let t:Table =
        {Table
            background="aqua", border-color="aqua",
            border-width=2pt, border-style="raised",
            cell-border-width=2pt, cell-border-style="sunken",
            halign="center"
        }
    {for i:int = 0 below 5 do
        {t.add
            row = i, column = 0, colspan = 3,
            {format "Row %d", i}
        }
    }
    {t.add
        row = 2,
        {row-prototype "A", "B", "C"}
    }
    t
}

{value
    let t:Table =
        {Table
            background="aqua", border-color="aqua",
            border-width=2pt, border-style="raised",
            cell-border-width=2pt, cell-border-style="sunken",
            halign="center"
        }
    {for i:int = 0 below 5 do
        {t.add
            row = i, column = 0, colspan = 3,
            {format "Row %d", i}
        }
    }
    {t.add
        row = 2, column = 0,
        {row-prototype "A", "B", "C"}
    }
    t
}

{value let t:Table=
    {Table cell-border-width=1pt, cell-border-color="blue",
           border-width=1pt, border-color="blue",
           {row-prototype {text font-size=12pt, Big},
                {text font-size=24pt, Hello}},
           {row-prototype {text font-size=16pt, Bigger},
                {text font-size=16pt, Goodbye}},
           {row-prototype {text font-size=24pt, Biggest},
                {text font-size=8pt, Maybe}}}
    || Insert a row at row number 2
    {t.insert-row 2}
    || Add content to the newly added row
    {t.add row=2,
           {row-prototype {text color="red", New},
                {text color="red", Text}}}
    t
}