{import * from CURL.ENGINE.BROWSER}
{def applet-source:String =
    {stringify
        {curl 8.0 applet}
        {import * from CURL.ENGINE.BROWSER}

        
        {define-class public CustomSplashScreenSubApplet
          {inherits SplashScreenSubApplet}
          
          {constructor public {default}
            {construct-super}
          }

          {method public open {create-main-body}:Graphic
            {return
                {VBox
                    hstretch? = true,
                    framelike-stretch? = true,
                    self.title-frame,
                    {hrule},
                    self.image-frame,
                    self.progress-bar-frame,
                    {hrule},
                    self.footer-frame
                }
            }
          }
        }

        {after 0s do
            {CustomSplashScreenSubApplet}
        }
    }
}

{CommandButton
    label = "Custom Splash Screen",
    {on Action do
        {SplashScreen.setup
            splash-applet-url = {string-url applet-source},
            title = "アプレットのロード中 ...",
            footer = "テスト例 ..."
        }
        || indeterminateなプログレスバーを表示します。
        {SplashScreen.set-progress-bar-indeterminate}
        || 作業が終わるまで2秒必要と仮定しています。
        {sleep 2s}
        {SplashScreen.set-progress-bar  max = 10.0}
        {sleep 1s}
        
        || ループに入り、ループの中でスリープし、
        || なんらかの作業をしているような状態にします。
        let val:double = 0
        {for i = 0 below 50 do
            set val = val + 0.2
            {SplashScreen.set-progress-bar-value val}    
            {sleep 0.1s}
        }
        || 完了したので、スプラッシュスクリーンを破棄します。
        {SplashScreen.destroy}
    }
}