リスト コントロール

{ListBox
    height = 0.5in,
    "red", "green", "blue"
}

{ListBox
    height = 1.0in,
    "red", "green", "blue",
    {ListSeparator},
    "teal", "purple", "orange"
}

{let lb:DropdownList = 
    {DropdownList
        value = "alpha",
        {ListValueItem 
            "alpha",
            label = {image source = {url "../../default/images/a-icon.gif"}}
        },
        {ListValueItem 
            "bravo",
            label = {image source = {url "../../default/images/b-icon.gif"}}
        },
        {ListValueItem 
            "charlie",
            label = {image source = {url "../../default/images/c-icon.gif"}}
        },
        {on ValueChanged at lb:DropdownList do
            {popup-message lb.value}
        }
    }
}
{value lb}

{let model:DefaultListModel  =
    {DefaultListModel
        "red", "green", "blue",
        "-",
        "teal", "purple", "orange"
    }
}
{HBox
    height = 3cm,
    valign = "top",
    {ListBox
        data-model = model,
        list-item-creation-proc =
            {proc {val:any}:ListItem
                {if (val isa String) and (val == "-") then
                    {return
                        {ListSeparator}
                    }
                 else
                    {return
                        {ListValueItem 
                            val, 
                            label = {text color =  val, {value val}}
                        }
                    }
                }
            }
    },
    {ListBox
        data-model = model
    },
    {CommandButton
        label = "add color",
        {on Action at cb:CommandButton do
            {model.append "cyan"}
        }
    }
}

{let message:VBox = {VBox}}
{VBox
    {italic Select at most one of the following pets:},
    {ListBox
        selection-policy = "single",
        height = 1.0in,
        "Aardvark", "Cat", "Dog", "Elephant", "Gnu", "Zebra",
        {on ValueFinished at lb:ListBox do
            {for x:any in lb.value do
                {message.add x}
            }
            {popup-message message}
            {message.clear}
        }
    }
}

{VBox
    {italic Select one or more options:},
    {ListBox
        style="checkbutton",
        height=0.8in,
        vorigin="top",
        "Moon roof", "Side air bags", "6-CD Changer", "Alarm System",
        {on ValueFinished at box:ListBox do
            {popup-message
                {text You have now selected  {value box.value.size} options.}
            }
        }
    }
}

{let list-of-states:DefaultListModel =
    {DefaultListModel
        "Alabama", "Alaska", "Arizona", "Arkansas", "California",
        "Colorado", "Connecticut", "Delaware", "Florida", "Georgia",
        "Hawaii", "Idaho", "Illinois", "Indiana", "Iowa",
        "Kansas", "Kentucky", "Louisiana", "Maine", "Maryland",
        "Massachusetts", "Michigan", "Minnesota", "Mississippi", "Missouri",
        "Montana", "Nebraska", "Nevada", "New Hampshire", "New Jersey",
        "New Mexico", "New York", "North Carolina", "North Dakota", "Ohio",
        "Oklahoma", "Oregon", "Pennsylvania", "Rhode Island", "South Carolina",
        "South Dakota", "Tennessee", "Texas", "Utah", "Vermont",
        "Virginia", "Washington", "West Virginia", "Wisconsin", "Wyoming"
    }
}
{DropdownList
    prompt = "Choose a state:",
    data-model = list-of-states,
    dropdown-height = 2in,
    {on ValueFinished at ddl:DropdownList do
        {popup-message
            {text You have chosen the state of {value ddl.value}.}
        }
    }
}

{spaced-hbox
    valign = "center",
    {ColorDropdown
        width = 1in,
        border-width = 2pt,
        initial-color = "green",
        {on ValueFinished at c:ColorDropdown do
            set c.border-color = c.value
        }
    },
    {ColorDropdown
        width = 1in,
        border-width = 2pt,
        no-color-value = "",
        color-array = {StringArray "pink", "cyan", "teal"},
        {on ValueFinished at c:ColorDropdown do
            {if c.value == "" then
                {unset-option-by-name c, "border-color"}
             else
                set c.border-color = c.value
            }
        }
    }
}

{value
    let favorite:Dynamic =
        {Dynamic
            {text init}
        }
    let combi:ComboBox =
        {ComboBox
            {on ValueFinished at combo:ComboBox do
                || 動的な変数(favorite) を更新します。
                set favorite.value = combo.value
            }
        }

    {combi.append "8pt"}
    {combi.append "10pt"}
    {combi.append "18pt"}
    {combi.append "24pt"}
    {combi.append "28pt"}

    || ComboBox を初期化します。
    set combi.value = "10pt"
    set favorite.value = combi.value


    {Dialog
        {spaced-vbox halign = "center",
            {paragraph Select your favorite font size:},
            combi,
            {CommandButton label = "Show font size",
                {on Action do
                    let your-size:Distance = {combi.value.to-int}*1pt
                    {if your-size < 5pt or your-size > 40pt then
                        {popup-message title = "Bad font size",
                            {text Please choose a better font size.}


                        }
                     else
                        {popup-message
                            title = "Your font size",
                            {text
                                font-size = your-size,
                                An example of your favorite font size!
                            }
                        }
                    }
                }
            },
            {text
                font-family = "sans-serif",
                font-weight = "bold",
                Your favorite font size is {value favorite}.
            }
        }
    }
}