コントロールで発生するイベント

Control の各クラスはインタラクティブな動作に対応するように設計されていて、ユーザーがマウスやキーボードの操作によってトリガする 1 つ以上のイベントに応答します。前述のとおり、コントロールメカニズムの UI 部分では一般的な (または「未加工」) イベントを受け取り、コントロールで適合可能なイベントを発生させます。ダイナミックイベントハンドラをコントロールにアタッチし、発生したコントロール適合イベントへの応答としてこれらを実行することができます。

たとえば、ユーザーがテキストフィールドに入力したときにテキストフィールドの value プロパティを変化させるだけでなく、テキストフィールドで ValueChanged イベントを発生させます。続いてユーザーが [Enter] キーを押すかテキストフィールドの外側にカーソルを移動すると、そこで ValueFinished イベントを発生させます。 ValueChanged および ValueFinished は、コントロールのみに適合可能な 2 つのイベントタイプの例です。具体的には、これらはValue コントロール (value に関連付けられているコントロール) に適合されるものです。

さまざまなコントロール適合イベントは、通常ユーザーのコントロール操作に応じてコントロールで発生します。次のようなイベントが含まれます。

各コントロールには、このような特定のイベントを発生させるユーザー操作が組み込まれています。たとえば、CheckButton ではボックスをクリックすると ValueChanged イベントと ValueFinished イベントが発生し、value プロパティも変わります。詳細は、『API リファレンスマニュアル』で各コントロールのセクションを参照してください。

ダイナミックイベントハンドラ

Control の各インスタンスを作成するときにインスタンスのイベントハンドラを記述して、インスタンスで発生するイベントに応答して実行することができます。このようなイベントハンドラは、

ダイナミックイベントハンドラ と呼ばれ、on 式を使ってオブジェクトにアタッチするのが最も一般的です。 EventTarget.add-event-handler を呼び出してダイナミックイベントハンドラを EventTarget にアタッチすることもできます。『API リファレンスマニュアル』の各 Control のセクションで、発生するイベントの詳細を確認してください。

コントロールで発生するイベント以外に、コントロールコンテナで発生するイベントがあります。

Commit は Dialog およびそれに含まれるコントロールで発生するイベントです。通常は Dialog.commit によってトリガされます。このダイナミックおよびスタティックイベントハンドラを記述できます。
詳細は「Commit イベント」のセクションを参照してください。
DialogShow は、ダイアログが表示されたときに発生します。つまり、ダイアログがポップアップ表示されたとき、別のビューに移動したとき、またはアプレット内に配置された後で発生します。通常は Dialog.show によってトリガされます。このイベントのみに対応するダイナミックイベントハンドラを記述できます。

イベントおよびイベント処理の詳細については、「イベント」の章も参照してください。 GuiEvent.consume メソッドの使用に関する説明に特に注意してください。このメソッドにより、追加の変更ハンドラによって処理したり再発生させなければならないイベントをターゲットが消費することができます。

次の例は、ValueChanged イベントのダイナミックハンドラを追加したチェックボタンを示しています。ボタンをクリックすると、ボタンで ValueChanged イベントが発生するのを確認してみてください。さらに、ダイナミックイベントハンドラによりボタンのラベルが変わります。

例: ダイナミック ValueChanged ハンドラのアタッチされたチェックボタン

{let my-value:Dynamic =
    {Dynamic "My initial value is false"}
}
{CheckButton
    value = false, || initially unchecked
    label = my-value, || this label will be updated dynamically
    {on ValueChanged at cb:CheckButton do
        {
            set my-value.value = "My current value is " & cb.value
        }
    }
}

スタティックイベントハンドラ

ダイアログとコントロールは GuiEventTarget クラスも継承していることから、特別なスタティックイベントハンドラ メソッドを備えています。このメソッドは、任意のクラスで標準イベントの 1 つが発生したときに、そのすべてのオブジェクトで既定の応答を提供するものです。詳細は「スタティックイベントハンドラ」のセクションで解説しています。以下の点に注意してください。

これらのスタティックイベントハンドラは、指定ターゲットやイベント対してユーザー定義のダイナミックイベントハンドラが実行された後でのみ実行されます。
イベントの多くはコントロールに適用されません。
標準コントロールクラスの一部として提供されるスタティックイベントハンドラのほとんどは、既定では何も実行しません。

すべての Control に関連する主なスタティックイベントハンドラの一部を次に示します。特定のタイプのコントロールすべてについて異なる既定の動作を定義する場合は、そのコントロールクラスのサブクラスを作成し、1 つ以上のスタティックイベントハンドラの動作をオーバーライドする新しいメソッドを記述してから、そのサブクラスを使ってコントロールを作成します。「既存のコントロールの変更」のセクションで使用例を参照してください。

on-focus-in: FocusIn イベントに応答します。このイベントはフォーカスがグラフィカルオブジェクトに移動すると発生します。
on-focus-out: FocusOut イベントに応答します。このイベントはフォーカスがグラフィカルオブジェクトから離れると発生します。
on-key-event: KeyEvent に応答します。このイベントは、キーボード操作により生成される一般的なイベントを表します。
on-key-press: KeyPress に応答します。このイベントは、キーボードの押し下げにより生成されるイベントを表す KeyEvent のサブクラスです。
on-pointer-enter: PointerEnter イベントに応答します。このイベントはポインタがターゲットに入ると発生します。ボタンを「ロールオーバー」状態に設定できます。
on-pointer-leave: PointerLeave イベントに応答します。このイベントはポインタがターゲットから離れると発生します。ボタンを「標準」状態に設定できます。
on-commit: Commit イベントに応答します。このイベントは、通常ダイアログの [適用] および [OK] ボタンが押されると発生します。通常これらのボタンは、ダイアログ内のすべてのコントロールの現在値を得るために押されます。

次のセクションでは、Dialog 内のコントロールおよびそれ自体で発生する Commit イベントについて説明します。

ダイアログの利点の 1 つは、ユーザーの選択内容すべてを 1 つのユーザー操作、つまりボタンクリックで収集できる機能にあります。 Curl 言語には、組み込みの [OK] ボタンを備えたモーダルダイアログを作成するショートカットプロシージャがあります。ユーザーがこのボタンをクリックすると、すべてのコントロールおよびダイアログ自体で Commit イベントが発生します。さらにポップアップダイアログの場合は、[OK] ボタンによりダイアログを閉じるというメッセージをダイアログに送ります。

ただし、Curl 言語が提供するモーダルダイアログを使用しない場合は、独自の [OK] または [適用] ボタンを作成して同じ操作を実行することができます。次のセクションでは、これらのボタンの実装に関して Commit イベントがどのように使用されるかについて説明します。

[OK]、[適用] および [キャンセル] ボタンの作成

[OK] ボタンの実装方法は次のとおりです。

CommandButton を作成します。
最初の Action イベントに対するボタンのイベントハンドラでは、[OK]/[適用] ボタンを含む Dialog の Dialog.commit を呼び出します。
Dialog.commit は、まずダイアログ内のすべてのコントロールで、次にダイアログ自体で Commit イベントを発生させます。この後さまざまなコントロールの on-commit イベントハンドラが実行されてから、それらを含むダイアログの on-commit イベントハンドラが実行されます。
ボタンの Commit イベントのイベントハンドラでは、可能な場合に Dialog.close を呼び出してダイアログを閉じます。

[適用] ボタンを含むダイアログを作成することもできます。 [適用] ボタンの実装は、最後のステップを除いて [OK] ボタンと同じです。つまり、Dialog.close は呼び出されず、したがってポップアップダイアログの場合でも閉じません。

popup-message プロシージャで生成されるダイアログなどには、オプションで [キャンセル] ボタンを含めることができます。 [キャンセル] ボタンの実装方法は次のとおりです。

CommandButton を作成します。
ボタンの Action イベントのイベントハンドラでは、ボタンを含む Dialog で Dialog.close を呼び出します。
この場合、Commit イベントは発生せず、on-commit ハンドラは実行されません。

次の例では、Dialog.commit メソッドがどのように使用されているかを示しています。このメソッドでは、最初にダイアログに含まれるすべての Control で、続いて Dialog 自体で Commit イベントが発生します。

例: Dialog.commit メソッドの使用

{define-proc
    {order-coffee milk?:bool, coffee-type:String}:void
    {popup-message
        {if milk? then
            {text Here is some {value coffee-type} with milk!}
         else
            {text Sorry, no milk with your {value coffee-type}!}
        }
    }
}
{value
    let milk?:bool = true
    let coffee-type:String = "Kenyan"
    let b:CommandButton =
        {CommandButton
            label = "Show non-modal dialog"
        }
    || construct the dialog
    let rf:RadioFrame =
        {radio-buttons
            "Kenyan",
            "Arabica",
            "Sumatran",
            value = "Kenyan"
        }
    let cb:CheckButton =
        {CheckButton
            label = "with milk?"}
    let ok:CommandButton =
        {CommandButton
            label = "OK",
            {on Action do
                {ok.dialog.commit}
                {ok.dialog.close Dialog.ok}
            }
        }
    let cancel:CommandButton =
        {CommandButton
            label = "Cancel",
            {on Action do
                {cancel.dialog.close Dialog.cancel}

            }
        }
    let dialog:Dialog =
        {Dialog
            {spaced-vbox
                rf,
                cb,
                {spaced-hbox ok, cancel}
            },
            {on com:Commit do
                set milk? = cb.value
                set coffee-type = rf.value
                {order-coffee milk?, coffee-type}
                {com.consume}
            },
            {on WindowClose do
                set b.enabled? = true
            }
        }
    {b.add-event-handler
        {on Action at b:CommandButton do
            let v:#View = {b.get-view}
            {unless dialog.open? do
                set b.enabled? = false
                {dialog.show modal? = false, owner = v}
            }
        }
    }
    {value b}
}