{let hf:HttpForm =
    {HttpForm
        ||通信先URL
        {url “http://localhost:8080/sample/SampleService“},

        ||HTTPリクエストメソッド
        ||HttpRequestMethod.post or HttpRequestMethod.get
        method = HttpRequestMethod.post,
       
        ||サーバーに送信される要求のエンコード タイプ
        ||HttpFormData.urlencoded-mime-type or HttpFormData.multipart-mime-type
        encoding = HttpFormData.urlencoded-mime-type,

        ||パラメータに使用する既定の文字エンコード
        default-character-encoding = “utf8”,
       
        width = {add-stretch},
        {spaced-vbox
            margin = 5pt,
            halign = “right”,
            {HBox spacing = 5pt, width = {add-stretch},
                {TextFlowBox “name”},
                {TextField name = “name”, width = 3cm},
                {TextFlowBox “address”},
                {TextField name = “address”, width = 3cm},
                {Fill}
            },
            {CommandButton
                label = “検索”,
                {on Action do
                    {with-busy-cursor
                        {try
                            {with-open-streams response:#TextInputStream =
                                ||リクエスト送信
                                {hf.submit-open
                                    character-encoding={get-character-encoding-by-name “utf8”}}
                             do
                                {if-non-null response then
                                    ||レスポンス解析→データオブジェクト生成
                                    let rs:#RecordSet = {parse-response response}
                                    set rg.record-source = rs
                                }
                            }
                         catch e:HttpException do
                            {popup-message “通信エラーが発生しました。:” & e.message}
                         catch e:Exception do
                            {popup-message “エラーが発生しました。:” & e.message}
                        }
                    }
                }
            }
        }
    }
}

|| —————————————————————
|| HttpFormData生成プロシージャ
|| —————————————————————
{define-proc public {create-http-form-data
                        mime-type:String = HttpFormData.urlencoded-mime-type,
                        default-character-encoding:CharEncoding = CharEncoding.utf8,
                        request-parameter:{HashTable-of String, String} = {{HashTable-of String, String}}
                    }:HttpFormData
    ||デフォルトのHttpFormData作成
    let form-data:HttpFormData = {HttpFormData
                                     mime-type                  = mime-type,
                                     default-character-encoding = default-character-encoding
                                 }
    {for s:String key k:String in request-parameter do
        {form-data.append {HttpFormStringParam k, s}}
    }
   
    {return form-data}
}

|| —————————————————————
|| データ取得プロシージャ
|| —————————————————————
{define-proc public {get-data
                        url-string:String,
                        request-parameter:{HashTable-of String, String}
                    }:RecordSet
    let http-file:HttpFile = {{url url-string}.resolve} asa HttpFile
    let form-data:HttpFormData = {create-http-form-data request-parameter = request-parameter}
    let record-set:#RecordSet

    {with-busy-cursor
        {try
            {with-open-streams response:#TextInputStream =
                ||リクエスト送信
                {http-file.http-read-open
                    character-encoding = “utf8”,
                    request-method　= HttpRequestMethod.post,
                    request-data = form-data
                }
             do
                {if-non-null response then
                    set record-set = {parse-response response}
                    {record-set.commit}
                }
            }
         catch he:HttpException do
            {popup-message “通信エラーが発生しました。:” & he.message}
         catch e:Exception do
            {popup-message “エラーが発生しました。:” & e.message}
        }
    }

    {return {non-null record-set}}
}

|| —————————————————————
|| レスポンス解析プロシージャ
|| —————————————————————
{define-proc public {parse-response
                        tis:TextInputStream
                    }:#RecordSet
    ||SAXParserインスタンスを生成
    let parser:SAXParser = {SAXParser}
    ||XMLハンドラインスタンスを生成
    let response-handler:ResponseHandler = {ResponseHandler}
    ||SAXParserにXMLハンドラをセット
    {parser.set-content-handler response-handler}
    ||TextInputStreamをSAXParserのインプット用に変換
    let source:InputSource = {InputSource character-stream = tis}
    ||解析処理
    {parser.parse source}
    {return response-handler.record-set}
}

|| —————————————————————
|| XMLハンドラクラス
|| —————————————————————
{define-class public ResponseHandler {inherits DefaultHandler}
  field private _record-set:#RecordSet
  field private _data:StringBuf
 
  {getter {record-set}:#RecordSet
    {return self._record-set}
  }
 
  {constructor public {default}
    set self._data = {StringBuf}
    {construct-super}
  }
 
  {method public {start-document}:void}
 
  {method public {start-element url:String, name:String, qname:String, atts:Attributes}:void
    {switch name
     case “RecordSet” do
     case “Record” do
        {self.start-element-record atts}
    }
  }
 
  {method public {characters ch:StringBuf, start:int, length:int}:void
    {self._data.clear}
    {self._data.concat {ch.substr start, length}}
  }
 
  {method public {end-element uri:String, name:String, qname:String}:void
    {switch name
     case “RecordSet” do
        {if-non-null self._record-set then
            {self._record-set.commit}
        }
     case “Record” do
    }
  }
 
  {method public {end-document}:void}
 
  {method private {start-element-record atts:Attributes}:void
    {if self._record-set == null then
        let fields-array:{Array-of RecordField} = {{Array-of RecordField}}
        {for i:int = 0 below {atts.get-length} do
            {if-non-null {atts.get-local-name i} then
                {fields-array.append {RecordField {non-null {atts.get-local-name i}}}}
            }
        }
        set self._record-set = {RecordSet {RecordFields {splice fields-array}}}
    }
    let record:Record = {self._record-set.new-record}
    {for i:int = 0 below {atts.get-length} do
        {if-non-null {atts.get-local-name i} then
            {record.set {non-null {atts.get-local-name i}}, {atts.get-value i}}
        }
    }
    {self._record-set.append record}
  }
}

|| —————————————————————
|| レスポンス解析プロシージャ
|| —————————————————————
{define-proc public {parse-response
                        tis:TextInputStream
                    }:RecordSet
    let response-xml:XDMElement = {build-xml preserve-whitespace? = true, tis}.root
    let e:XmlElaboration =
        {xml-elaboration
            {“RecordSet” {…:RecordData}:RecordSet
                {RecordSet
                    {RecordFields
                        {RecordField “name”, domain = String},
                        {RecordField “address”, domain = String},
                        {RecordField “phone”, domain = String},
                        {RecordField “number”, domain = String},
                        {RecordField “amount”, domain = String}
                    },
                    {splice …}}
            }
            {“Record” RecordData}
        }
    {return {e.elaborate response-xml} asa RecordSet}
}