説明
イメージの表示方法は、例示した方法でこのオブジェクトに対して利用できるセッターで制御できます。さらに、ImageShape は Shape.transformation フィールドを使用して、その位置、回転、およびスケールを他の形状と同じ方法で決定します。オプションで変換に含まれる回転またはスケールを無視して、「ビルボード」イメージとして参照されるものを提示することもあります。これは既定であり、ImageShape.fixed-transformation? によって制御されます。
拡大縮小しない、もしくはタイル処理をしないと仮定すると、イメージのピクセルは Renderer2d.pixel-size によって定義されるように論理的なスクリーンにマップされます。これは高解像度のディスプレイでは、 1 : 1 の比率とはなりません。また、画像が印刷される時には、他の Shapeに関連する画像のサイズが保護されるように、(Distance 単位で測定された) 同じサイズが使用されます。
注意事項
通常、回転されたイメージは表示されません。Canvas.use-host-rendering? をfalseに設定することで、この機能（及び他の機能も）をサポートするように出来ます。ただし、この結果パフォーマンスが悪くなることに留意してください。このクラスは以下のオプションを使用します。:
このオブジェクトは、"ImageShape"のスタイル ルールを記述することでスタイル化することが出来ます。
例
次の例では、fixed-transformation? を除く ImageShape のすべてのパラメータを示しています。GraphicShape も ImageShape と同じアルゴリズムを固定変換に使用します。このアルゴリズムの効果を示す例については、GraphicShape の説明を参照してください。
| 例 | |
 | |
{import * from CURL.GUI.SHAPES}
{import * from CURL.GRAPHICS.IMAGEFILTER}
{let shape:ImageShape =
{ImageShape
translation = {Distance2d 4cm, 4cm},
{filter-pixmap
scale,
{Pixmap.from-url
{url "curl://install/docs/default/images/adria.jpg"}
},
scale = 50%
}
}
}
{VBox
spacing = .125cm,
halign = "center",
border-width = 1px,
"tiles (x, y):",
{HBox
{TextField
width = .5in,
value = {format "%.2f", shape.tiles.x},
{on ValueFinished at tf:TextField do
set shape.tiles =
{Double2d {tf.value.to-double}, shape.tiles.y}
}
},
{TextField
width = .5in,
value = {format "%.2f", shape.tiles.y},
{on ValueFinished at tf:TextField do
set shape.tiles =
{Double2d shape.tiles.x, {tf.value.to-double}}
}
}
}
}
{VBox
spacing = .125cm,
halign = "center",
border-width = 1px,
"pixmap-scale (x, y):",
{HBox
{TextField
width = .5in,
value = {format "%.2f", shape.pixmap-scale.x},
{on ValueFinished at tf:TextField do
set shape.pixmap-scale =
{Double2d {tf.value.to-double}, shape.pixmap-scale.y}
}
},
{TextField
width = .5in,
value = {format "%.2f", shape.pixmap-scale.y},
{on ValueFinished at tf:TextField do
set shape.pixmap-scale =
{Double2d shape.pixmap-scale.x, {tf.value.to-double}}
}
}
}
}
{VBox
spacing = .125cm,
halign = "center",
border-width = 1px,
"pixmap-offset (x, y):",
{HBox
{TextField
width = .5in,
value = {format "%.2f", shape.pixmap-offset.x},
{on ValueFinished at tf:TextField do
set shape.pixmap-offset =
{Double2d {tf.value.to-double}, shape.pixmap-offset.y}
}
},
{TextField
width = .5in,
value = {format "%.2f", shape.pixmap-offset.y},
{on ValueFinished at tf:TextField do
set shape.pixmap-offset =
{Double2d shape.pixmap-offset.x, {tf.value.to-double}}
}
}
}
}
{HBox
spacing = .125cm,
border-width = 1px,
{VBox
spacing = .125cm,
halign = "center",
"halign: ",
{TextField
width = .5in,
value = shape.halign,
tooltip =
{Tooltip
{text
Valid alignments are
{monospace left}, {monospace
center}, {monospace origin},
{monospace right}, or a number
in the range of 0.0 to 1.0.
}
},
{on ValueFinished at field:TextField do
let (val:double, chars:int) = {field.value.to-double}
{if chars == field.value.size then
set shape.halign = val
else
set shape.halign = field.value
}
}
}
},
{VBox
spacing = .125cm,
halign = "center",
"valign: ",
{TextField
width = .5in,
value = shape.valign,
tooltip =
{Tooltip
{text
Valid alignments are
{monospace top}, {monospace
center}, {monospace origin},
{monospace bottom}, or a number
in the range of 0.0 to 1.0.
}
},
{on ValueFinished at field:TextField do
let (val:double, chars:int) = {field.value.to-double}
{if chars == field.value.size then
set shape.valign = val
else
set shape.valign = field.value
}
}
}
}
}
{Canvas
width = 8cm,
height = 8cm,
border-width = 1px,
shape
}
|