{import * from CURL.GUI.SHAPES}

{let parent:RectangleShape =
    {RectangleShape
        {GRect .5cm, .5cm, .5cm, .5cm},
        translation = {Distance2d 2.5cm, 2.5cm}
    }
}
{value
    {parent.add
        {CommandButton
            horigin = "left",
            label = "Try to hit me!",
            {on Action do
                {if parent.color == FillPattern.black then
                    set parent.color = FillPattern.gray
                 else
                    set parent.color = FillPattern.black
                }
            }
        }
    }

    let start:DateTime = {DateTime}
    let tmr:Timer =
        {parent.animate
            frequency=30fps, || 30 frames per second
            repeat = 0,
            {on TimerEvent do
                let elapsed:Time = {start.elapsed}
                {parent.set-translation-in-parent 2.5cm + 1cm * {sin elapsed * (30deg / 1s)}, 2.5cm}
                {parent.set-rotation elapsed * (20deg / 1s)}
            }
        }
    let run-button:CommandButton =
        {CommandButton label = "Start",
            {on Action do
                set start = {DateTime}
                set tmr.repeat = 500
            }
        }
    let stop-button:CommandButton =
        {CommandButton label = "Stop",
            {on Action do
                set tmr.repeat = 0
                
            }
        }
    {HBox
        spacing = .125cm,
        run-button,
        stop-button
    }
}

{Canvas
    width = 10cm,
    height = 10cm,
    parent
}