棒を使用してデータ系列をプロットする
説明
既定では、BarLayer.y-axis-data の各メンバ内のそれぞれのレコードについて、BarLayer が RectangleShape を生成します。生成された Shape は BarLayer.series-shapes で見つかります。
Shape の外観と動作はいくつかの方法でカスタマイズできます。最も簡単な方法はオプションを使用することです。他のグラフ コンポーネントの場合と同様、Shape は、それがある場所またはその上のどこにでも非ローカル オプション セットを使用して制御することができます。たとえば、bar-border-width を設定すれば、四角形の境界線の太さを変更できます。
また、BarLayer.shape-factory を使用すれば、Shape の作成プロセスをオーバーライドすることもできます。これは非常に用途の広い手法です。これを使用すれば、個々の Shape のオプション値を変更したり、Shape の Tooltip を提供したり、まったく種類の異なる Shape を一緒に生成したりさえできます。
注意事項
重要: 正しくプロットするために、BarLayer には特殊なタイプの X 軸オブジェクトが必要です。余分の目盛りの作成、および、目盛りにではなく目盛り間のデータ ポイントの位置付けが必要になるためです。これを行うタイプの軸には EnumeratedBarChartAxis (データ ベース) と DefaultBarChartAxis (レコード インデックス ベース) があります。
既定では、BarLayer.maybe-create-x-axis によってこれらのいずれかが自動的に作成されます。しかし、場合によっては、これが行われません。X 軸を手動で設定する場合は、BarLayer.maybe-create-x-axis を完全に回避します。あるいは、この ChartLayer が行う前に、LayeredChart.layers 内の別の ChartLayer が X 軸を作成すると、X 軸は作成されません。
こうした場合、X 軸を直接制御する必要があります。独自にこの軸を作成して、適切な軸スロットに割り当てることができます (たとえば、LayeredChart.bottom-axis )。次の例はこのことを示しています。必要であれば、代わりに LayeredChart.x-axis-factory を使用して、自動作成プロセスを制御できます。
次の非ローカル オプションは、特に BarLayer に関連しています。
グラフへのその他のオブジェクトの追加については、ChartLayer を参照してください。
このオブジェクトは、"BarLayer"のスタイル ルールを記述することによってスタイル化することが出来ます。
例
| 例 | |
 | |
{import * from CURL.GUI.CHARTS}
{import * from CHARTS-DOC,
location = "../docstring-support/gui/charts-doc.scurl"
}
{define-proc package {h-gradient
start-color:FillPattern,
highlight-color:FillPattern,
end-color:FillPattern,
highlight-pos:double = 0.2
}:FillPattern
{return
{LinearGradientFillPattern
{Fraction2d 0, 0},
{Fraction2d 1, 0},
{Spectrum.from-envelope
start-color,
0.0,
highlight-color,
highlight-pos,
end-color,
1.0
}
}
}
}
{let chart:LayeredChart =
{LayeredChart
width = 15cm,
height = 6cm,
color-palette =
{new {Array-of FillPattern},
{h-gradient "gray", "white", "gray"},
{h-gradient "blue", "lavender", "steelblue"},
{h-gradient "red", "mistyrose", "crimson"},
{h-gradient "purple", "lavender", "blueviolet"},
{h-gradient "lime", "mintcream", "green"}
},
bar-border-width = 2px,
bottom-axis =
{EnumeratedBarChartAxis
{ChartDataSeries sample-records, "Name"}
},
{BarLayer
sample-records,
"Age",
"Points",
shape-factory =
{proc {layer:BarLayer,
rectangle:GRect,
record:Record,
record-index:int,
series-index:int,
border-width:any,
border-line-style:LineStyle
}:Shape
let constant stock-shape:Shape =
{BarLayer.default-shape-factory
layer,
rectangle,
record,
record-index,
series-index,
border-width,
border-line-style
}
{stock-shape.add-event-handler
{on PointerEnter at s:Shape do
set s.border-color = FillPattern.yellow
}
}
{stock-shape.add-event-handler
{on PointerLeave at s:Shape do
{unset s.border-color}
}
}
{return stock-shape}
}
}
}
}
{Canvas
width = chart.width,
height = chart.height,
chart
}
{RadioFrame
{HBox
spacing = 4pt,
{RadioButton radio-value = ChartStackingMode.none, value = true},
{RadioButton radio-value = ChartStackingMode.stacked},
{RadioButton radio-value = ChartStackingMode.percent}
},
{on ValueFinished at rf:RadioFrame do
let constant layer:BarLayer = chart.layers[0] asa BarLayer
set layer.stacking-mode = rf.value asa ChartStackingMode
}
}
|
