{import * from CURL.GUI.CHARTS}
{import * from CHARTS-DOC,
    location = "../docstring-support/gui/charts-doc.scurl"
}

{LayeredChart
    width = 15cm,
    height = 6cm,
    {LineLayer
        sample-records,
        "Wins",
        "Points",
        "Age",
        {DataSeriesColorPair
            {ChartDataSeries sample-records, "Wins"},
            "steelblue"
        }
    }
}

{import * from CURL.GUI.CHARTS}
{import * from CHARTS-DOC,
    location = "../docstring-support/gui/charts-doc.scurl"
}

{let chart:LayeredChart =
    {LayeredChart
        width = 15cm,
        height = 6cm,
        {BarLayer
            sample-records,
            "Age",
            x-axis-data = {ChartDataSeries sample-records, "Name"}
        },
        {LineLayer
            sample-records,
            "Wins"
        },
        {on ChartLayoutChanged do
            || Give big winners a gold diamond
            let constant layer:ChartLayer = chart.layers[1]
            let constant map:ChartDataMapping =
                {layer.get-data-mapping layer.y-axis-data[0]}


            let index:int = 0
            {for record in sample-records do
                {if record["Wins"] asa int >= 6 then
                    let constant (pos:Distance2d, y-was-null?:bool) =
                        {map.get-position record, index}
                    
                    {if not y-was-null? then
                        || Don't add shapes for records with null values.
                        let constant size:Distance =
                            3 * {sqrt 2} * {layer.get-display-context}.pixel-size
                        {layer.add
                            {RectangleShape
                                {GRect size, size, size, size},
                                translation = pos,
                                rotation = 45deg,
                                color = "gold",
                                tooltip =
                                    {Tooltip
                                        {format
                                            "%s got %d wins!",
                                            record["Name"],
                                            record["Wins"]
                                        }
                                    }
                            }
                        }
                    }
                }
                
                {inc index}
            }
        }
    }
}

{value chart}

{import * from CURL.GUI.CHARTS}
{import * from CHARTS-DOC,
    location = "../docstring-support/gui/charts-doc.scurl"
}

{let bar-display:TextDisplay = {TextDisplay width = 4cm}}
{let line-display:TextDisplay = {TextDisplay width = 4cm}}

{let chart:LayeredChart =
    {LayeredChart
        width = 15cm,
        height = 6cm,
        {BarLayer
            sample-records,
            "Age",
            x-axis-data = {ChartDataSeries sample-records, "Name"}
        },
        {LineLayer
            sample-records,
            "Wins"
        },
        {on e:PointerMotion do
            let layer:ChartLayer = chart.layers[0]
            let inverse-mapping:ChartInverseDataMapping =
                {non-null {layer.get-inverse-data-mapping layer.y-axis-data[0]}}
            let (x:any, y:any) = {inverse-mapping.get-values e.x, e.y}
            set bar-display.value = x & ", " & y

            set layer = chart.layers[1]
            set inverse-mapping =
                {non-null {layer.get-inverse-data-mapping layer.y-axis-data[0]}}
            set (x, y) = {inverse-mapping.get-values e.x, e.y}
            set line-display.value = x & ", " & y
        }
    }
}

{Table
    cell-border-width = 1pt,
    cell-border-color = FillPattern.silver,
    {row-prototype
        font-weight = FontWeight.bold,
        {text BarLayer (Age)},
        {text LineLayer (Wins)}
    },
    {row-prototype bar-display, line-display},
    {row-prototype
        {cell-prototype
            colspan = 2,
            chart
        }
    }
}

{import * from CURL.GUI.CHARTS}
{import * from CHARTS-DOC,
    location = "../docstring-support/gui/charts-doc.scurl"
}

{let x-axis-only?:bool = true}
{let record-display:TextDisplay = {TextDisplay}}
{let value-display:TextDisplay = {TextDisplay}}

{let chart:LayeredChart =
    {LayeredChart
        width = 15cm,
        height = 6cm,
        {ScatterLayer
            sample-records,
            "Wins",
            x-axis-data = {ChartDataSeries sample-records, "Age"}
        },
        {on e:PointerMotion do
            || Transform coordinates from chart into one of its
            || children -- the plot area:
            let constant point-in-plot-area:Distance2d =
                {chart.plot-area.transformation.inverse-transform-point
                    {Distance2d e.x, e.y}
                }

            let layer:ChartLayer = chart.layers[0]
            let mapping:ChartDataMapping =
                {layer.get-data-mapping layer.y-axis-data[0]}
            let inverse-mapping:ChartInverseDataMapping =
                {non-null {layer.get-inverse-data-mapping layer.y-axis-data[0]}}
            let record:Record =
                {non-null
                    {layer.get-nearest-record-in-data
                        point-in-plot-area.x,
                        point-in-plot-area.y,
                        layer.y-axis-data[0],
                        mapping,
                        x-axis-only? = x-axis-only?
                    }
                }
            set record-display.value =
                {format
                    "Name: %s, points: %s, wins: %s, age: %s",
                    record["Name"],
                    record["Points"],
                    record["Wins"],
                    record["Age"]
                }

            let (x:any, y:any) = {inverse-mapping.get-values e.x, e.y}
            set value-display.value = x & ", " & y
        }
    }
}

{Table
    cell-border-width = 1pt,
    cell-border-color = FillPattern.silver,
    {row-prototype
        font-weight = FontWeight.bold,
        {text get-nearest-record-in-data results},
        {text ChartInverseDataMapping results}
    },
    {row-prototype record-display, value-display},
    {row-prototype
        {CheckButton
            label = "find nearest using x axis only?",
            value = x-axis-only?,
            {on ValueFinished at cb:CheckButton do
                set x-axis-only? = cb.value
            }
        },
        {CheckButton
            label = "chart is flipped?",
            value = chart.flipped?,
            {on ValueFinished at cb:CheckButton do
                set chart.flipped? = cb.value
            }
        }
    },
    {row-prototype
        {cell-prototype
            colspan = 2,
            chart
        }
    }
}

{import * from CURL.GUI.CHARTS}
{import * from CHARTS-DOC,
    location = "../docstring-support/gui/charts-doc.scurl"
}

{let chart:LayeredChart =
    {LayeredChart
        width = 15cm,
        height = 6cm,
        {BarLayer
            sample-records,
            "Age",
            "Points",
            x-axis-data = {ChartDataSeries sample-records, "Name"}
        }
    }
}

{value chart}

{CommandButton
    label = "Switch order",
    {on Action do
        let constant layer:ChartLayer = chart.layers[0]
        let constant temp:ChartDataSeries = layer.y-axis-data[0]
        set layer.y-axis-data[0] = layer.y-axis-data[1]
        set layer.y-axis-data[1] = temp

        || Here is the important method call:
        {layer.note-y-axis-data-array-changed}
    }
}

{import * from CURL.GUI.CHARTS}
{import * from CHARTS-DOC,
    location = "../docstring-support/gui/charts-doc.scurl"
}

{let chart:LayeredChart =
    {LayeredChart
        width = 12cm,
        height = 6cm,
        {LineLayer
            sample-records,
            "Age",
            "Points",
            "Height",
            x-axis-data = {ChartDataSeries sample-records, "Name"},
            symbols-at-data-points? = true
        }
    }
}

{value chart}

{CheckButton
    label = "Show Age?",
    value = true,
    {on ValueFinished at cb:CheckButton do
        let layer:ChartLayer = chart.layers[0]
        {layer.set-data-series-visibility 0, cb.value}
    }
}

{CheckButton
    label = "Show Points?",
    value = true,
    {on ValueFinished at cb:CheckButton do
        let layer:ChartLayer = chart.layers[0]
        {layer.set-data-series-visibility 1, cb.value}
    }
}

{CheckButton
    label = "Show Height?",
    value = true,
    {on ValueFinished at cb:CheckButton do
        let layer:ChartLayer = chart.layers[0]
        {layer.set-data-series-visibility 2, cb.value}
    }
}